\\% Pretty printing of factorizations.
\\ Author: Joerg Arndt
\\ License: GPL version 3 or later
\\ online at http://www.jjj.de/pari/
\\ version: 2011-January-19 (12:48)


print1fact(bla="", f, tx="*")=
{
    local(nf, p, x);
    print1(bla);
    nf = matsize(f)[1];
    for (k=1, nf,
        p = f[k,1];
        x = f[k,2];
        print1(p);
        if ( x!=1, print1("^", x) );
        if ( k<nf, print1(tx) );
    );
} /* ------- */

print1dfact(bla="", f, tx="*", d=1)=
{
    local(nf, p1f, x);
    print1(bla);
    nf = matsize(f)[1];
    for (j=1, nf,
        p1f = factor(f[j,1]-d);
        x = f[j,2];
        print1("(", d ," + ");
        print1fact("", p1f, tx);
        print1(")");
        if ( x!=1, print1("^", x) );
        if ( j<nf, print1(" ", tx, " ") );
    );
} /* ------- */

printp_fact(n, dv=0)=
{
    local(f,nf,d);
    print1(n);
    print1fact("  ==  1 + ", factor(n-1), " * ");

    if ( 0!=dv,
        for (k=1, length(dv),
            d=dv[k];
            print1w("\n  ==  ", d, 2, 1);
            print1fact(" + ", factor(n-d), " * ");
        );
    );
    print1("\n");
    f = factor(n);  nf = matsize(f)[1];
    print1fact("  == ", f, " * ");
    print1dfact("  == ", f, " *", 1);
    if ( 0!=dv,
        for (k=1, length(dv),
            d=dv[k];
            print1dfact("\n  == ", f, " *", d);
        );
    );
} /* ------- */

\\ ==== end of file ====